@ECHO OFF
ECHO WMP71W95.BAT - Install Windows Media Player 7.1 on Windows 95
ECHO Copyright (c) 2001 Rainbow Software (htttp://rainbow.ht.st)
ECHO.
IF NOT EXIST WMP7.EXE IF NOT EXIST SETUP_WM.EXE GOTO USAGE
IF NOT EXIST MP71.EXE GOTO USAGE
MKDIR %TEMP%\WMP7
IF EXIST SETUP_WM.EXE GOTO SETUP
START /W WMP7.EXE /T:%TEMP%\WMP7 /C /Q
GOTO NEXT
:SETUP
COPY SETUP_WM.EXE %TEMP%\WMP7 >NUL
:NEXT
MKDIR %TEMP%\WMP71
START /W MP71.EXE /T:%TEMP%\WMP71 /C /Q
COPY %TEMP%\WMP7\SETUP_WM.EXE %TEMP%\WMP71 >NUL
ECHO Y|DEL %TEMP%\WMP7\*.* >NUL
RMDIR %TEMP%\WMP7
START /W %TEMP%\WMP71\SETUP_WM.EXE
ECHO Y|DEL %TEMP%\WMP71\*.* >NUL
RMDIR %TEMP%\WMP71
GOTO QUIT
:USAGE
ECHO This program assumes that these files are present in the current directory:
ECHO.
ECHO  WMP7.EXE     - Windows Media Player 7.0 Install Package (10MB)
ECHO    or
ECHO  SETUP_WM.EXE - Install Program from Windows Media Player 7.0 (270KB)
ECHO    and
ECHO  MP71.EXE     - Windows Media Player 7.1 Install Package (9.5MB)
ECHO.
ECHO Download these files and put them in the same directory as this program
:QUIT